>        I'm having trouble using ALLIN1 when sending messages to the
>network.  I'm not running PMDF nor any management tool.  I'm trying
>to address messages the following way:
>
>        IN%"bitnet address"@PSI%psinumber@MRGATE
>
>        (Obs: when using MAIL, I do: PSI%psinumber::IN%"bitnet address")
>
>        Things don't work like I expected to.  Nor even a sign, the remote
>node don't tell anything about the routing.  I just don't know what to do.
>Could any kind soul help me ?  I'd like you to send the answers directly
>to me (SUP_LEO@C53000.PETROBRAS.ANRJ.BR), and I'll post a summary to the
>list.
>
>        Regards,
>                Leonardo.

(I tired to send this direct, but it bounced)

The problem is with message router.  I am experiencing similar 
problem with DECUS UUCP, except that I do get error messages.  
Apparently message router doesn't pass the return address to 
foreign mail protocols correctly.  If anyone has a fix you you, 
let me know.  I work around the problem by putting the following 
SPECIAL.COM and SPECIAL.CMU in OA$SITE_LIB_SHARE.  This allows me
to intercept all mail that is prefixed with an _ and send it via
VMS mail.  I also add the UUCP%"..." notation since Allin1 doesn't 
seem to pass quotation marks very well.
-----------------Cut Here---------------------------------------
$ !	OALIB:SPECIAL.COM	V2.1A	Last edited: 4-Nov-1985
$ !	Electronic Mail Subsystem
$ !	Deliver mail to the "SPECIAL" destination
$ !	1/25/89 fixed Loop1: to allow ! in TO symbol to pass thru  Dale Weathers
$ !	10Jun89 fixed MAIL to actually use mail instead of global symbol DJM
$ !	15NOV90 twiddled with things to keep quotes right.
$	ASSIGN/USER NLA0: SYS$OUTPUT
$	ASSIGN/USER NLA0: SYS$ERROR
$	ON WARNING THEN GOTO NOT_SENT
$	MY_NODE	 =	F$GETSYI("NODENAME")
$	QUOTE[0,8] = 34
$
$
$ SETUP_PARAM:
$	WRITE OAMAILBOX "OA GET OA$PROFIL_DIRECT"
$	@DCLMAILBOX:
$	DIRECT		=	RESULT
$	WRITE OAMAILBOX "OA GET #MAILFILE"
$	@DCLMAILBOX:
$	FILE		=	RESULT
$	FILESPEC	=	DIRECT + FILE
$	WRITE OAMAILBOX "OA GET #MAILSUBJ"
$	@DCLMAILBOX:
$	SUBJ		=	RESULT
$	WRITE OAMAILBOX "OA GET #MAILADDR"
$	@DCLMAILBOX:
$	TO		=	RESULT
$! now check to see if this is a UUCP address
$  	    at_loc  = F$LOCATE("@",TO)
$           bang_loc= F$LOCATE("!",TO)
$           len     = F$LENGTH(TO)
$           IF at_loc .lt. len .or. bang_loc .lt. len
$             THEN 	!its a UUCP address
$		TO = F$FAO("UUCP%!AS!AS!AS",QUOTE,TO - "_",QUOTE)
$   	      ELSE	!must be VMSmail
$		TO = TO - "_"
$             ENDIF
$! can't just use MAIL uucp%"..." 'cause it bombs on @ signs.
$ send_it = F$FAO("SEND/NOCC/SUBJ=!AS!AS!AS !AS",QUOTE,SUBJ,QUOTE,FILESPEC)
$ OPEN/WRITE mail_TEMP MAIL_TEMP.COM
$ w := write MAIL_TEMP
$ W "$ MAIL := MAIL"
$ W "$ MAIL"
$ W send_it
$ W TO
$ W "$ EXIT"
$ close mail_temp
$ @mail_temp
$ IF $STATUS THEN GOTO DONE
$
$ NOT_SENT:
$	Status = '$STATUS
$	WRITE OAMAILBOX "OA GET OA$STATUS=""''STATUS'"""
$	@DCLMAILBOX:
$ DONE:
$       delete mail_temp.com;
$	EXIT
-----------------Cut Here-----------------------------------
$ !	OALIB:SPECIAL.CMU for access to UNIX - By Dan McDonald
$ !	All addresses with a single underscores that contain either
$ !	an @ or a ! will be considered UUCP addresses and will be sent via
$ !	VMS mail to UUCP%"..."
$ !	eg: _bobh@txsil ==> UUCP%"bobh@txsil"
$ !	
$ !	After some experimentation, I found it preferable to add UUCP%"
$ !	 in SPECIAL.COM instead of SPECIAL.CMU
$ !
$ !!!	ASSIGN/USER NLA0: SYS$OUTPUT
$ !!!	ASSIGN/USER NLA0: SYS$ERROR
$	ON WARNING THEN GOTO NOT_SENT
$
$       QUOTE[0,8] = 34
$
$ SETUP_PARAM:
$
$  address = p1
$  at_loc  = F$LOCATE("@",address)
$  bang_loc= F$LOCATE("!",address)
$  len     = F$LENGTH(address)
$  IF at_loc .lt. len .or. bang_loc .lt. len
$  THEN 	!its a UUCP address
$	address = F$EDIT(address,"LOWERCASE")
$	no_under= address - "_"	!strip leading _ for info
$	info    = F$FAO("UUCP user !AS",no_under)
$	emaddr  = address
$
$	status = "Message will be sent via DECUS UUCP V1.2"
$
$   ELSE	!must be VMSmail
$	address = F$EDIT(address,"UPCASE")
$	no_under= address - "_"	!strip leading _ for info
$	info   = F$FAO("VMSmail user !AS",no_under)
$	emaddr = address
$	status = "Message will be sent with VMSmail"
$   ENDIF
$  
$ WRITE OAMAILBOX "OA SAVE #EMDADDRESSINFO " + info
$	@DCLMAILBOX:
$	WRITE OAMAILBOX "OA SAVE #EMDADDRESS " + emaddr
$	@DCLMAILBOX:
$	WRITE OAMAILBOX "OA GET OA$DISPLAY=""''status'"""
$	@DCLMAILBOX:
$
$	EXIT

Hope this helps!


******************************************************************************
Dan McDonald                     * UUCP         ...letni!txsil!dalsil!mcdonald
Summer Institute of Linguistics  * Internet mcdonald@dalsil.txsil.lonestar.org
7500 W Camp Wisdom Rd            * Phone    (214)709-2400x2327
Dallas, TX 75236                 * FAX      (214)709-3387
******************************************************************************