From:	MERC::"uunet!CRVAX.SRI.COM!RELAY-INFO-VAX" 24-JAN-1993 17:23:11.74
To:	info-vax@sri.com
CC:	
Subj:	Re: DECWindows and Startup States

Erek Adams writes:
>Hello Info-Vaxers,
>
>	I've got a fairly simple question for you.  Is is possible under
>DECWindows to have everything startup as an Icon?  In DECW$SM_GENERAL.DAT there
>is a line that reads 'sm.startup_state:      iconified'  Now I know what this
>does for the Session Manager, but is there a way to force everything else to be
>an Icon on startup?  I'd like to be able to force DecTerms, Eve, and BookReader
>into an icon without cluttering up my screen.
>
Ask and ye shall receive:

******************************
A1MAIL$DW_DEFAULTS.DAT;1

Mail.initialState:	3

******************************
DECW$BOOKREADER.DAT;1

BookreaderLibrary.initialState:		    3

******************************
DECW$CALENDAR.DAT;1

DECW$CALENDAR.initialState: 3

******************************
DECW$MAIL.DAT;1

Mail.initialState:	3

******************************
DECW$MESSAGEPANEL.DAT;1

ctrl.startup_state:	iconified

******************************
DECW$SM_GENERAL.DAT;1

sm.startup_state:	iconified

******************************
DECW$TERMINAL_DEFAULT.DAT;1

DECW$TERMINAL.initialState:			    3

******************************
NOTES$DEFAULTS.DAT;1

NOTES$DEFAULTS*MAIN_SHELL.initialState:		3


>	On a slightly different note, is there anyway to start up a Decterm on
>node X from node Y _without_ logging into node Y and issuing a
>'create/term=decterm/detach' on it (node Y)?  As is to do that and keep my
>current decterms free, I have to set host and issue the command manually.  Can
>I do it remotely?  If so how?
>
$   VFY = 'F$VERIFY( 0 )
$!==============================================================================
$!
$!  DECW$REMOTE.COM
$!
$!	Start a remote DECWindows application
$!
$!==============================================================================
$   SET NOON
$   APPLICATION_LIST = "/DECTERM/CLOCK/BOOKREADER/CALC/CALENDAR/CARDFILER/CDA_VIEWER/FILEVIEW/MAIL/NOTEPAD/PAINT/PUZZLE/VAXNOTES/"
$   MODE = F$MODE()
$   IF MODE .EQS. "NETWORK" THEN GOTO NETWORK_STARTUP
$
$   IF P1 .EQS. "" THEN INQUIRE P1 "Remote node"
$   IF P1 .EQS. "" THEN EXIT
$   P1 = P1 - "::"
$   IF P2 .EQS. "" THEN P2 = "DECTERM"
$
$   OPEN/READ/WRITE TASK 'P1'::"TASK=UT:DECW$REMOTE"
$   IF .NOT. $STATUS THEN GOTO EXIT
$   WRITE TASK P2
$   READ/END=EXIT/ERROR=EXIT TASK STATUS
$   WRITE SYS$OUTPUT STATUS
$   CLOSE/NOLOG TASK
$   GOTO EXIT
$
$NETWORK_STARTUP:
$
$   REMNODE = F$PARSE("SYS$NET",,,"NODE","SYNTAX_ONLY") - "::"
$   CURNODE = F$TRNLNM("SYS$NODE") - "::"
$   OPEN/READ/WRITE/ERROR=EXIT NET SYS$NET
$   READ/ERROR=EXIT/END=EXIT NET P2
$   IF REMNODE .NES. CURNODE
$   THEN
$	TRANSPORT = "DECNET"
$   ELSE
$	TRANSPORT = "LOCAL"
$   ENDIF
$   SET MESSAGE SYS$MESSAGE:DECW$TERMINALMSG
$   WRITE SYS$OUTPUT "[Starting application ''P2'...]"
$   DEFINE/NOLOG SYS$ERROR NET:
$   IF F$LOCATE( "/" + P2 + "/", APPLICATION_LIST ) .EQ. F$LENGTH( APPLICATION_LIST )
$   THEN
$	GOTO MISCELLANEOUS
$   ELSE
$	GOTO 'P2'
$   ENDIF
$
$DECTERM:
$   SET DISPLAY/CREATE/TRANSPORT='TRANSPORT'/NODE='REMNODE'
$   CREATE/TERMINAL/DETACH/LOGGED_IN-
	/WINDOW_ATTRIBUTES=(INITIAL_STATE=ICON,-
			    TITLE="DECterm on ''CURNODE'",-
			    ICON_NAME="''CURNODE'")
$   GOTO EXIT
$
$CLOCK:
$   SET DISPLAY/CREATE/TRANSPORT='TRANSPORT'/NODE='REMNODE'
$   CLOSE/NOLOG NET
$   SET PROCESS/NAME="Clock_''REMNODE'"
$   RUN SYS$SYSTEM:DECW$CLOCK
$   SET DISPLAY/NOPERMANENT
$   GOTO EXIT
$BOOKREADER:
$   SET DISPLAY/CREATE/TRANSPORT='TRANSPORT'/NODE='REMNODE'
$   CLOSE/NOLOG NET
$   SET PROCESS/NAME="Book_''REMNODE'"
$   RUN SYS$SYSTEM:DECW$BOOKREADER
$   SET DISPLAY/NOPERMANENT
$   GOTO EXIT
$CALC:
$   SET DISPLAY/CREATE/TRANSPORT='TRANSPORT'/NODE='REMNODE'
$   CLOSE/NOLOG NET
$   SET PROCESS/NAME="Calc_''REMNODE'"
$   RUN SYS$SYSTEM:DECW$CALC
$   SET DISPLAY/NOPERMANENT
$   GOTO EXIT
$CALENDAR:
$   SET DISPLAY/CREATE/TRANSPORT='TRANSPORT'/NODE='REMNODE'
$   CLOSE/NOLOG NET
$   SET PROCESS/NAME="Calendar_''REMNODE'"
$   RUN SYS$SYSTEM:DECW$CALENDAR
$   SET DISPLAY/NOPERMANENT
$   GOTO EXIT
$CARDFILER:
$   SET DISPLAY/CREATE/TRANSPORT='TRANSPORT'/NODE='REMNODE'
$   CLOSE/NOLOG NET
$   SET PROCESS/NAME="CardFiler_''REMNODE'"
$   RUN SYS$SYSTEM:DECW$CARDFILER
$   SET DISPLAY/NOPERMANENT
$   GOTO EXIT
$CDA_VIEWER:
$   SET DISPLAY/CREATE/TRANSPORT='TRANSPORT'/NODE='REMNODE'
$   CLOSE/NOLOG NET
$   SET PROCESS/NAME="CDA_View_''REMNODE'"
$   VIEW/INTERFACE=DECWINDOWS
$   SET DISPLAY/NOPERMANENT
$   GOTO EXIT
$FILEVIEW:
$   SET DISPLAY/CREATE/TRANSPORT='TRANSPORT'/NODE='REMNODE'
$   CLOSE/NOLOG NET
$   SET PROCESS/NAME="FileView_''REMNODE'"
$   RUN SYS$SYSTEM:VUE$MASTER
$   SET DISPLAY/NOPERMANENT
$   GOTO EXIT
$MAIL:
$   SET DISPLAY/CREATE/TRANSPORT='TRANSPORT'/NODE='REMNODE'
$   CLOSE/NOLOG NET
$   SET PROCESS/NAME="Mail_''REMNODE'"
$   RUN SYS$SYSTEM:DECW$MAIL
$   SET DISPLAY/NOPERMANENT
$   GOTO EXIT
$NOTEPAD:
$   SET DISPLAY/CREATE/TRANSPORT='TRANSPORT'/NODE='REMNODE'
$   CLOSE/NOLOG NET
$   SET PROCESS/NAME="Notepad_''REMNODE'"
$   RUN SYS$SYSTEM:DECW$NOTEPAD
$   SET DISPLAY/NOPERMANENT
$   GOTO EXIT
$PAINT:
$   SET DISPLAY/CREATE/TRANSPORT='TRANSPORT'/NODE='REMNODE'
$   CLOSE/NOLOG NET
$   SET PROCESS/NAME="Paint_''REMNODE'"
$   RUN SYS$SYSTEM:DECW$PAINT
$   SET DISPLAY/NOPERMANENT
$   GOTO EXIT
$PUZZLE:
$   SET DISPLAY/CREATE/TRANSPORT='TRANSPORT'/NODE='REMNODE'
$   CLOSE/NOLOG NET
$   SET PROCESS/NAME="Puzzle_''REMNODE'"
$   RUN SYS$SYSTEM:DECW$PUZZLE
$   SET DISPLAY/NOPERMANENT
$   GOTO EXIT
$VAXNOTES:
$   SET DISPLAY/CREATE/TRANSPORT='TRANSPORT'/NODE='REMNODE'
$   CLOSE/NOLOG NET
$   SET PROCESS/NAME="VAXnotes_''REMNODE'"
$   NOTES/INTERFACE=DECWINDOWS
$   SET DISPLAY/NOPERMANENT
$   GOTO EXIT
$
$MISCELLANEOUS:
$   SET DISPLAY/CREATE/TRANSPORT='TRANSPORT'/NODE='REMNODE'
$   CLOSE/NOLOG NET
$   SHOW DISPLAY
$   'P2'
$   SET DISPLAY/NOPERMANENT
$   GOTO EXIT
$EXIT:
$   CLOSE/NOLOG TASK
$   CLOSE/NOLOG NET
$   IF VFY THEN SET VERIFY


    colin sewell
    h.a.simons ltd.
    vancouver, bc
    "simons/g=colin/s=sewell"@mhs.attmail.com